Half-Life и Adrenaline Gamer форум

/*
    v0.1 - [05.10.2011] First release
   
   http://aghl.ru/forum/ - Russian Half-Life and Adrenaline Gamer Community
*/

#include <amxmodx>
#include <fakemeta_util>

/* <<< OPTIONS >>> */

//#define Half_Life         // remove comment for Half-Life (Для Халф-лайф удалите комментарий)
#define BEAM_NOISE      0   // noise
#define BEAM_BRIGHTNESS      128.0   // brightness
#define BEAM_WIDTH      5.0   // width

#define   COLOR_I         {255.0, 0.0, 0.0} // team = terrorists, or weapon = crossbow 
#define   COLOR_II      {0.0, 0.0, 255.0} // team = counter-terrorists, or weapon = python

/* <<< END >>> */

#define SNIPER_WEAPON_CS(%1)   1 << %1 & (1 << CSW_SCOUT | 1 << CSW_AWP | 1 << CSW_G3SG1 | 1 << CSW_SG550)
#define SNIPER_WEAPON_HL(%1)   1 << %1 & (1 << HLW_PYTHON | 1 << HLW_CROSSBOW)

enum _:DATA
{
   BEAM,
   IN_ZOOM
}

new g_SpriteIndex,
g_PlayerBeam[33][DATA]

#define PLUGIN      "HL_Laser_Beam"
#define VERSION     "0.1"
#define AUTHOR      "KORD_12.7" // & Turanga_Leela

public plugin_precache()
{
   g_SpriteIndex = precache_model("sprites/laserbeam.spr")
}

public plugin_init()
{
   register_plugin(PLUGIN, VERSION, AUTHOR);
   register_event("CurWeapon", "zoom_event", "be", "1=1")
   register_forward(FM_AddToFullPack, "hide_beam")
   register_forward(FM_PlayerPostThink, "id_post_think", 1)
   register_event("DeathMsg", "client_dead", "a")
}

public hide_beam(entState, e, ent, host, iHostFlags, iPlayer, pSet)
{
#if !defined Half_Life
   if(ent == g_PlayerBeam[host][BEAM] && g_PlayerBeam[host][IN_ZOOM])
#endif   
#if defined Half_Life
   // **********
   //if(pev_valid(ent) && pev(ent, pev_owner) == host && ent == g_PlayerBeam[host][BEAM])
   if(ent == g_PlayerBeam[host][BEAM] && g_PlayerBeam[host][IN_ZOOM])
#endif   
   {
         
      
      //set_es(entState, ES_Effects, get_es(entState, ES_Effects)|EF_NODRAW)
      //client_print(host, print_chat, "Player: %d", host)
      set_visibility(ent, 0)   
   }
}

public client_disconnect(id)
{
   g_PlayerBeam[id][IN_ZOOM] = 0
   set_visibility(g_PlayerBeam[id][BEAM], 0)
}

public client_dead()
{
   new id = read_data(2)
   
   g_PlayerBeam[id][IN_ZOOM] = 0
   set_visibility(g_PlayerBeam[id][BEAM], 0)
}

public client_putinserver(id)
{
   if(!g_PlayerBeam[id][BEAM])
      g_PlayerBeam[id][BEAM] = BeamCreate(id | 0x1000)
}

set_visibility(ent, mode)
{
   fm_set_entity_visibility(ent, mode)
}

public zoom_event(id)
{
   new beam = g_PlayerBeam[id][BEAM], weapon = read_data(2)
#if !defined Half_Life   
   if(SNIPER_WEAPON_CS(weapon) && pev(id, pev_fov) <= 40)
#endif   
#if defined Half_Life   
   if(SNIPER_WEAPON_HL(weapon) && pev(id, pev_fov) >= 20)
#endif   
   {
      g_PlayerBeam[id][IN_ZOOM] = 1   
#if !defined Half_Life
      set_pev(beam, pev_rendercolor, get_user_team(id) == 1 ? COLOR_I : COLOR_II)
#endif      
#if defined Half_Life      
      set_pev(beam, pev_rendercolor, weapon == 6 ? COLOR_I : COLOR_II)      
#endif         
      set_visibility(beam, 1)
   }
   
   else
   {
      //client_print(host, print_chat, "Player: %d", host)
      g_PlayerBeam[id][IN_ZOOM] = 0
      set_visibility(beam, 0)
   }
}

public id_post_think(id)
{
   if(g_PlayerBeam[id][IN_ZOOM])
   {
      static Float: startPos[3]
      static Float: endPos[3]
      
      fm_get_aim_origin(id, startPos)
      pev(id, pev_origin, endPos)
      
      RelinkBeam(g_PlayerBeam[id][BEAM], startPos, endPos)
   }
}

//set_pev_func(ent, pev_is, param)
//{
   
   
//}

BeamCreate(const endIndex)
{
   new ent
   
   if(!(ent = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "beam")))) return 0
      
   //set_pev(ent, pev_owner, id)   
   
   set_pev(ent, pev_body, BEAM_NOISE)
   set_pev(ent, pev_renderamt, BEAM_BRIGHTNESS)   
   set_pev(ent, pev_flags, pev(ent, pev_flags) | FL_CUSTOMENTITY)
   set_pev(ent, pev_model, "sprites/laserbeam.spr")
   set_pev(ent, pev_modelindex, g_SpriteIndex)
   set_pev(ent, pev_scale, BEAM_WIDTH)
   set_pev(ent, pev_skin, endIndex)
   set_pev(ent, pev_rendermode, 1)
   
   return ent
}

RelinkBeam(const beam, const Float: startPos[3], const Float: endPos[3])
{
   static Float: mins[3], Float: maxs[3]

   mins[0] = floatmin(startPos[0], endPos[0])
   mins[1] = floatmin(startPos[1], endPos[1])
   mins[2] = floatmin(startPos[2], endPos[2])

   maxs[0] = floatmax(startPos[0], endPos[0])
   maxs[1] = floatmax(startPos[1], endPos[1])
   maxs[2] = floatmax(startPos[2], endPos[2])

   xs_vec_sub(mins, startPos, mins)
   xs_vec_sub(maxs, startPos, maxs)

   set_pev(beam, pev_mins, mins)
   set_pev(beam, pev_maxs, maxs)

   engfunc(EngFunc_SetSize, beam, mins, maxs)
   engfunc(EngFunc_SetOrigin, beam, startPos)
}