Half-Life и Adrenaline Gamer форум

Можете показать пример кода без использования weaponmod?, а то из за одной карты не хочется еще модуль грузить

_________________

Ну модуль можно загружать только на нужной карте, если что.

_________________

Vi Veri Veniversum Vivus Vici

это, конечно, понятно. но все же, если есть такая возможность, то хотелось бы обойтись стандартными модулями

_________________

Попробуй это:

public Player_SetAttackAnimation(const iPlayer)
{
   #define ACT_SWIM 6
   #define ACT_LEAP 8
   #define ACT_RANGE_ATTACK1 28
   #define ACT_HOVER 50
   
   // CBaseAnimating
   const m_flFrameRate = 23;
   const m_flGroundSpeed = 24;
   const m_flLastEventCheck = 25;
   const m_fSequenceFinished = 26;
   const m_fSequenceLoops = 27;
   
   // CBaseMonster
   const m_Activity = 88;
   const m_IdealActivity = 89;
   const m_szAnimExtention = 387;
   
   // Extra offsets
   const extra_offset_player = 5;
   const extra_offset_animating = 4;
   
   new iAnimDesired, iActivity = get_pdata_int(iPlayer, m_Activity, extra_offset_player);

   if (iActivity == ACT_SWIM || iActivity == ACT_LEAP || iActivity == ACT_HOVER)   
   {
      return;
   }
   
   new szAnim[64], Float: flFrameRate;
   
   get_pdata_string(iPlayer, m_szAnimExtention * 4, szAnim, charsmax(szAnim), 0, extra_offset_player * 4);
   format(szAnim, charsmax(szAnim), (pev(iPlayer, pev_flags) & FL_DUCKING) ? "crouch_shoot_%s" : "ref_shoot_%s", szAnim);
         
   if ((iAnimDesired = lookup_sequence(iPlayer, szAnim, flFrameRate)) == -1)
   {
      iAnimDesired = 0;
   }

   set_pev(iPlayer, pev_frame, 0.0);
   set_pev(iPlayer, pev_framerate, 1.0);
   set_pev(iPlayer, pev_sequence, iAnimDesired);
   set_pev(iPlayer, pev_animtime, get_gametime());
   
   set_pdata_int(iPlayer, m_fSequenceLoops, 0, extra_offset_animating);
   set_pdata_int(iPlayer, m_fSequenceFinished, 0, extra_offset_animating);
   set_pdata_int(iPlayer, m_Activity, ACT_RANGE_ATTACK1, extra_offset_player);
   set_pdata_int(iPlayer, m_IdealActivity, ACT_RANGE_ATTACK1, extra_offset_player);   
   
   set_pdata_float(iPlayer, m_flGroundSpeed, 0.0, extra_offset_animating);
   set_pdata_float(iPlayer, m_flFrameRate, flFrameRate, extra_offset_animating);
   set_pdata_float(iPlayer, m_flLastEventCheck, get_gametime(), extra_offset_animating);
}

В теории оно должно запустить аниму атаки текущего оружия на модели игрока.

Добавлено спустя 7 минут 29 секунд:
Проверил - работает.

_________________

Vi Veri Veniversum Vivus Vici

Спасибо, теперь буду ждать ответа от тестеров

_________________

К сожалению, это работает не совсем так как хотелось бы, правильная анимация проигрывается только на crowbar'е, на самом мече, слоте из под hornetgun, проигрывается анимация первичной атаки именно этого оружия. Есть ли возможность на любом слоте воспроизвести анимацию crowbar'а?

_________________

В коде выше замени

get_pdata_string(iPlayer, m_szAnimExtention * 4, szAnim, charsmax(szAnim), 0, extra_offset_player * 4);
format(szAnim, charsmax(szAnim), (pev(iPlayer, pev_flags) & FL_DUCKING) ? "crouch_shoot_%s" : "ref_shoot_%s", szAnim);

на

formatex(szAnim, charsmax(szAnim), (pev(iPlayer, pev_flags) & FL_DUCKING) ? "crouch_shoot_crowbar" : "ref_shoot_crowbar");

_________________

Vi Veri Veniversum Vivus Vici

Спасибо, то что нужно

_________________