#include <amxmodx>
#include <amxmisc>

new g_cmdLoopback[16]
new g_ResPtr
new g_HidePtr

public plugin_init()
{
   register_plugin("Slots Reservation", AMXX_VERSION_STR, "AMXX Dev Team")
   register_dictionary("adminslots.txt")
   register_dictionary("common.txt")
   g_ResPtr = register_cvar("amx_reservation", "0")
   g_HidePtr = register_cvar("amx_hideslots", "0")
   
   format(g_cmdLoopback, 15, "amxres%c%c%c%c", random_num('A', 'Z'), random_num('A', 'Z'), random_num('A', 'Z'), random_num('A', 'Z'))
   register_clcmd(g_cmdLoopback, "ackSignal")
}

public plugin_cfg()
{
   set_task(3.0, "MapLoaded")
}

public MapLoaded()
{
   if (!get_pcvar_num(g_HidePtr))
      return

   new maxplayers = get_maxplayers()
   new players = get_playersnum(1)
   new limit = maxplayers - get_pcvar_num(g_ResPtr)
   setVisibleSlots(players, maxplayers, limit)
}

public ackSignal(id)
{
   new lReason[64]
   format(lReason, 63, "%L", id, "DROPPED_RES")
   server_cmd("kick #%d ^"%s^"", get_user_userid(id), lReason)
   
   return PLUGIN_HANDLED
}

public client_authorized(id)
{
   new maxplayers = get_maxplayers()
   new players = get_playersnum(1)
   new limit = maxplayers - get_pcvar_num(g_ResPtr)

   if (access(id, ADMIN_RESERVATION) || (players <= limit))
   {
      if (get_pcvar_num(g_HidePtr) == 1)
         setVisibleSlots(players, maxplayers, limit)
      return PLUGIN_CONTINUE
   }
   
   client_cmd(id, "%s", g_cmdLoopback)

   return PLUGIN_HANDLED
}

public client_disconnect(id)
{
   if (!get_pcvar_num(g_HidePtr))
      return PLUGIN_CONTINUE

   new maxplayers = get_maxplayers()
   
   setVisibleSlots(get_playersnum(1) - 1, maxplayers, maxplayers - get_pcvar_num(g_ResPtr))
   return PLUGIN_CONTINUE
}

setVisibleSlots(players, maxplayers, limit)
{
   new num = players + 1

   if (players == maxplayers)
      num = maxplayers
   else if (players < limit)
      num = limit
   
   set_cvar_num("sv_visiblemaxplayers", num)
}